SUBROUTINE SEQHT(A,N,N1,W,B,T,L)
C
C     ALGORITHM SEQHT (SEQUENTIAL HOUSEHOLDER TRIANGULARIZATION)
C     FROM LAWSON,C.L. AND R.J.HANSON (1973)
C          SOLVING LEAST SQUARES PROBLEMS
C          PRENTICE HALL,INC., NEW JERSEY
C
C     W(N)  VECTOR OF COEFFICIENTS FOR PRESENT CASE
C     B     KNOWN CONSTANT FOR THE PRESENT CASE
C     T     ULP (Q=I+U*U(T)/(S*ULP))
C
C     ON THE FINAL CALL Q[A B] = A = R  D
C                                    0  E
C                                    0  0
C     (DIMENSIONED N1 BY N 1 1) (R IS UPPER TRIANGULAR)
C
C     LS   R  X  =  D      N1 >= N+2
C          0        E
C
      IMPLICIT REAL*8(A-H,O-Z)
      IMPLICIT INTEGER(I-N)
C
      DIMENSION A(N1,1),W(N)
      INTEGER P
C
C     INITIALLY (FIRST CALL) L IS SET TO ZERO
C     STEP 1  L IS INITIALLY SET TO 0
C     STEP 2  SUBROUTINE IS CALLED NCASES TIMES
C     STEP 3  M(I) = 1 ALWAYS
C
      P = L + 1
C
C     STEP 4
C
      DO 10 I=1,N
   10 A(P,I) = W(I)
      A(P,N+1) = B
C
C     STEP 5
C
      NP1 = MIN(N+1,P-1)
      IF(NP1.EQ.0) GO TO 30
      DO 20 I=1,NP1
   20 CALL H12(1,I,MAX(I+1,L+1),P,A(1,I),1,T,A(1,I+1),1,N1,N+1-I)
   30 CONTINUE
C
C     STEP 6
C
      L = MIN(N+1,P)
C
C     STEP 7  UPON THE FINAL CALL HOUSEHOLDER TRIANGULARIZATION IS
C             COMPLETE
C
      RETURN
      END